@echo off
REM updateLib.bat - batch file to update vxWorks library
REM
REM modification history
REM --------------------
REM 01b,07nov96,yp   added s to archive command and removed ranlib step
REM 01a,10jul96,yp   written
REM
REM DESCRIPTION
REM given the list of objects to update library with, construct the command
REM line and call the archiver. We do this from where the objects live as
REM oposed to where we are building so the archive need not carry the relative
REM path
REM
set CPU=%1
shift
set TOOL=%1
shift
set AR=%1
shift
set RANLIB=%1
shift
set RM=%1
shift
set UP=%1
shift
set LIBNAME=%1
shift
set LIBDIR=%1
shift
set OBJ=
:getnext
if "%1"=="" goto end
set OBJ=%OBJ% %1
shift
goto getnext
:end
cd %LIBDIR%
echo on
@echo %AR% crus  %UP%lib/%LIBNAME% %LIBDIR% %OBJ%
@echo off
%AR% crus ../%LIBNAME% %OBJ%
